DOMAIN

Домен (Domain) — один из объектов реляционной базы данных, при создании которого можно задать некоторые характеристики, а затем использовать ссылку на домен при определении столбцов таблиц, объявлении локальных переменных, входных и выходных аргументов в модулях PSQL.

В данном разделе рассматриваются синтаксис операторов создания, модификации и удаления доменов.Подробное описание доменов и их использования можно прочесть в главе Пользовательские типы данных — домены.

`CREATE DOMAIN`

Назначение

Создание нового домена.

Доступно в

DSQL, ESQL.

Синтаксис

CREATE DOMAIN name [AS] <datatype>
  [DEFAULT {<literal> | NULL | <context_var>}]
  [NOT NULL] [CHECK (<dom_condition>)]
  [COLLATE collation_name];

<datatype> ::=
    <scalar_datatype> | <blob_datatype> | <array_datatype>

<scalar_datatype> ::=  См. Синтаксис скалярных типов данных

<blob_datatype> ::= См. Синтаксис типа данных BLOB

<array_datatype> ::= См. Синтаксис массивов

<dom_condition> ::=
    <val> <operator> <val>
  | <val> [NOT] BETWEEN <val> AND <val>
  | <val> [NOT] IN (<val> [, <val> ...] | <select_list>)
  | <val> IS [NOT] NULL
  | <val> IS [NOT] DISTINCT <val>
  | <val> IS [NOT] {TRUE | FALSE | UNKNOWN}
  | <val> [NOT] CONTAINING <val>
  | <val> [NOT] STARTING [WITH] <val>
  | <val> [NOT] LIKE <val> [ESCAPE <val>]
  | <val> [NOT] SIMILAR TO <val> [ESCAPE <val>]
  | <val> <operator> {ALL | SOME | ANY} (<select_list>)
  | [NOT] EXISTS (<select_expr>)
  | [NOT] SINGULAR (<select_expr>)
  | (<dom_condition>)
  | NOT <dom_condition>
  | <dom_condition> OR <dom_condition>
  | <dom_condition> AND <dom_condition>


<operator> ::=
    <> | != | ^= | ~= | = | < | > | <= | >=
  | !< | ^< | ~< | !> | ^> | ~>

<val> ::= {
    VALUE
  | <literal>
  | <context_var>
  | <expression>
  | NULL
  | NEXT VALUE FOR genname
  | GEN_ID(genname, <val>)
  | CAST(<val> AS <cast_type>)
  | (<select_one>)
  | func(<val> [, <val> ...])
}

<cast_type> ::=
   <datatype>
  | [TYPE OF] domain
  | TYPE OF COLUMN rel.col

Table 1. Параметры оператора `CREATE DOMAIN`
Параметр	Описание
name	Имя домена.Может содержать до 63 символов.
datatype	Тип данных SQL.
literal	Литерал.
context_var	Любая контекстная переменная, тип которой совместим с типом данных домена.
dom_condition	Условие домена.
collation_name	Порядок сортировки.
charset	Набор символов.
select_one	Оператор `SELECT` выбирающий один столбец и возвращающий только одну строку.
select_list	Оператор `SELECT` выбирающий один столбец и возвращающий ноль и более строк.
select_expr	Оператор `SELECT` выбирающий несколько столбцов и возвращающий ноль и более строк.
expression	Выражение.
genname	Имя последовательности (генератора).
func	Скалярная функция.

Оператор CREATE DOMAIN создаёт новый домен.

В качестве базового типа домена можно указать любой тип данных SQL.